ScoobyNet.com - Subaru Enthusiast Forum - Get users name from computer name?

ScoobyNet.com - Subaru Enthusiast Forum (https://www.scoobynet.com/)

- Computer & Technology Related (https://www.scoobynet.com/computer-and-technology-related-34/)

- - Get users name from computer name? (https://www.scoobynet.com/computer-and-technology-related-34/588646-get-users-name-from-computer-name.html)

Get users name from computer name?

As above is it possible?

I can get the users ID on our network, using nbtstat -a computername.

But I need the users real name, any help appreciated thanks.

try this

Code:



' ***********************************************************************************************

' RetrieveLoggedOnUsers.vbs - DWallis 05/03/07

'

' Usage Cscript //NoLogo RetrieveLoggedOnUsers.Vbs computer1Name Computer2Name

' ***********************************************************************************************

 

' ***********************************************************************************************

' Check Script is being run with CSCRIPT

' ***********************************************************************************************

    

If UCase(Right(Wscript.FullName, 11)) = "WSCRIPT.EXE" Then

    strPath = Wscript.ScriptFullName

        Wscript.Echo "This script should be run under CScript." & vbCrLf & vbCrLf & "Re-Starting Under CScript"

    strCommand = "%comspec% /K cscript //NOLOGO " & Chr(34) & strPath & chr(34)

    Set objShell = CreateObject("Wscript.Shell")

    objShell.Run(strCommand)

    Wscript.Quit

End If



' ***********************************************************************************************

' Check Arguments Passed (Computer Names), If none are passed then default to local machine

' ***********************************************************************************************



If Wscript.Arguments.Count = 0 Then

    arrComputers = Array(".")

Else

    Dim arrComputers()

    For i = 0 to Wscript.Arguments.Count - 1

        Redim Preserve arrComputers(i)

        arrComputers(i) = Wscript.Arguments(i)

    Next

End If

 

For Each strComputer in arrComputers

        Set objWMIService = GetObject("winmgmts:" & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2") 

        Set colComputers = objWMIService.ExecQuery ("Select * from Win32_ComputerSystem")

 

        For Each objComputer in colComputers

                    Wscript.Echo "ComputerName: " & strComputer & " UserName: " & objComputer.UserName

        Next

Next

I just use Kix

Would that be any could

Kix is just a scripting language, you would still need to query the remote machine to find the users that have an explorer.exe process running or using wmi as I did..

I can also use kix if you want it writing in that, but that involves a download, where as cscript / wscript shouldnt.

David

That looks awesome Dave, but as I'm a complete coding noob, how do I run it? :)

Just save it as a .vbs and run it? Or something (cscript) else? Thanks.

save it as a vbs file, for example RetrieveLoggedOnUsers.Vbs

Then in a command prompt do:

Cscript //NoLogo RetrieveLoggedOnUsers.Vbs computerName AnotherComputer Name

You can pass either one computer name or multiple computernames.

You will need admin rights on the remote pc though.

David

Ace, works a treat:thumb:

Quote:

Originally Posted by David_Wallis (Post 6720436)

Ah, sorry didn't read the original question correctly!

Quote:

Originally Posted by David_Wallis (Post 6722295)

DOH! completely missed the usage line.

It works a treat thanks alot Dave :thumb: